summaryrefslogtreecommitdiff
path: root/Debian
diff options
context:
space:
mode:
authorjoey <joey>2000-03-03 03:44:42 +0000
committerjoey <joey>2000-03-03 03:44:42 +0000
commit57cd028e69472a1d2ade68a474a45641c65ff7bb (patch)
tree77e316ab5d0d69f75e6ec8aab7a39aab133a13d5 /Debian
parentf60fc64ac3128ed3a352fc3fae521cbf8c932a42 (diff)
r340: * Patch from Jorgen `forcer' Schaefer <forcer at mindless.com> (much
modified)to make dh_installwm use new window manager registration method, update-alternatives. Closes: #52156, #34684 (latter bug is obsolete) * Fixed $dh{flavor} to be upper-case. * Deprecated dh_installemavcsen --number; use --priority instead. Also, the option parser requires the parameter be a number now. And, dh_installwm now accepts --priority, and window manager packages should start using it. * dh_installwm now behaves like a proper debhelper command, and reads debian/<package>.wm too. This is a small behavior change; filenames specified on the command line no longer apply to all packages it acts on. I can't belive this program existed for 2 years with such a glaring problem; I guess most people don't need ot register 5 wm's in 3 sub-packages. Anyway, it can handle such things now. :-) * Moved Dh_*.pm to /usr/lib/perl5/Debian/Debhelper. *big* change.
Diffstat (limited to 'Debian')
-rw-r--r--Debian/Debhelper/Dh_Getopt.pm193
-rw-r--r--Debian/Debhelper/Dh_Lib.pm371
2 files changed, 564 insertions, 0 deletions
diff --git a/Debian/Debhelper/Dh_Getopt.pm b/Debian/Debhelper/Dh_Getopt.pm
new file mode 100644
index 0000000..1e52109
--- /dev/null
+++ b/Debian/Debhelper/Dh_Getopt.pm
@@ -0,0 +1,193 @@
+#!/usr/bin/perl -w
+#
+# Debhelper option processing library.
+#
+# Joey Hess GPL copyright 1998.
+
+package Debian::Debhelper::Dh_Getopt;
+use strict;
+
+use Debian::Debhelper::Dh_Lib;
+use Getopt::Long;
+use Exporter;
+#use vars qw{@ISA @EXPORT};
+#@ISA=qw(Exporter);
+#@EXPORT=qw(&aparseopts); # FIXME: for some reason, this doesn't work.
+
+my (%options, %exclude_package);
+
+# Passed an option name and an option value, adds packages to the list
+# of packages. We need this so the list will be built up in the right
+# order.
+sub AddPackage { my($option,$value)=@_;
+ if ($option eq 'i' or $option eq 'indep') {
+ push @{$options{DOPACKAGES}}, GetPackages('indep');
+ $options{DOINDEP}=1;
+ }
+ elsif ($option eq 'a' or $option eq 'arch') {
+ push @{$options{DOPACKAGES}}, GetPackages('arch');
+ $options{DOARCH}=1;
+ }
+ elsif ($option eq 'p' or $option eq 'package') {
+ push @{$options{DOPACKAGES}}, $value;
+ }
+ elsif ($option eq 's' or $option eq 'same-arch') {
+ push @{$options{DOPACKAGES}}, GetPackages('same');
+ $options{DOSAME}=1;
+ }
+ else {
+ error("bad option $option - should never happen!\n");
+ }
+}
+
+# Add a package to a list of packages that should not be acted on.
+sub ExcludePackage { my($option,$value)=@_;
+ $exclude_package{$value}=1;
+}
+
+# Add another item to the exclude list.
+sub AddExclude { my($option,$value)=@_;
+ push @{$options{EXCLUDE}},$value;
+}
+
+# This collects non-options values.
+sub NonOption {
+ push @{$options{ARGV}}, @_;
+}
+
+# Parse options and return a hash of the values.
+sub parseopts {
+ undef %options;
+
+ my $ret=GetOptions(
+ "v" => \$options{VERBOSE},
+ "verbose" => \$options{VERBOSE},
+
+ "i" => \&AddPackage,
+ "indep" => \&AddPackage,
+
+ "a" => \&AddPackage,
+ "arch" => \&AddPackage,
+
+ "p=s" => \&AddPackage,
+ "package=s" => \&AddPackage,
+
+ "s" => \&AddPackage,
+ "same-arch" => \&AddPackage,
+
+ "N=s" => \&ExcludePackage,
+ "no-package=s" => \&ExcludePackage,
+
+ "n" => \$options{NOSCRIPTS},
+ "noscripts" => \$options{NOSCRIPTS},
+
+ "x" => \$options{INCLUDE_CONFFILES}, # is -x for some unknown historical reason..
+ "include-conffiles" => \$options{INCLUDE_CONFFILES},
+
+ "X=s" => \&AddExclude,
+ "exclude=s" => \&AddExclude,
+
+ "d" => \$options{D_FLAG},
+ "remove-d" => \$options{D_FLAG},
+ "dirs-only" => \$options{D_FLAG},
+
+ "r" => \$options{R_FLAG},
+ "no-restart-on-upgrade" => \$options{R_FLAG},
+
+ "k" => \$options{K_FLAG},
+ "keep" => \$options{K_FLAG},
+
+ "P=s" => \$options{TMPDIR},
+ "tmpdir=s" => \$options{TMPDIR},
+
+ "u=s", => \$options{U_PARAMS},
+ "update-rcd-params=s", => \$options{U_PARAMS},
+ "dpkg-shlibdeps-params=s", => \$options{U_PARAMS},
+ "dpkg-gencontrol-params=s", => \$options{U_PARAMS},
+
+ "l=s", => \$options{L_PARAMS},
+
+ "m=s", => \$options{M_PARAMS},
+ "major=s" => \$options{M_PARAMS},
+
+ "V:s", => \$options{V_FLAG},
+ "version-info:s" => \$options{V_FLAG},
+
+ "A" => \$options{PARAMS_ALL},
+ "all" => \$options{PARAMS_ALL},
+
+ "no-act" => \$options{NO_ACT},
+
+ "init-script=s" => \$options{INIT_SCRIPT},
+
+ "sourcedir=s" => \$options{SOURCEDIR},
+
+ "destdir=s" => \$options{DESTDIR},
+
+ "number=i" => \$options{PRIORITY}, # deprecated
+ "priority=i" => \$options{PRIORITY},
+
+ "flavor=s" => \$options{FLAVOR},
+
+ "<>" => \&NonOption,
+ );
+
+ if (!$ret) {
+ error("unknown option; aborting");
+ }
+
+ # Check to see if -V was specified. If so, but no parameters were
+ # passed, the variable will be defined but empty.
+ if (defined($options{V_FLAG})) {
+ $options{V_FLAG_SET}=1;
+ }
+
+ # If we have not been given any packages to act on, assume they
+ # want us to act on them all. Note we have to do this before excluding
+ # packages out, below.
+ if (! defined $options{DOPACKAGES} || ! @{$options{DOPACKAGES}}) {
+ if ($options{DOINDEP} || $options{DOARCH} || $options{DOSAME}) {
+ # User specified that all arch (in)dep package be
+ # built, and there are none of that type.
+ error("I have no package to build");
+ }
+ push @{$options{DOPACKAGES}},GetPackages();
+ }
+
+ # Remove excluded packages from the list of packages to act on.
+ my @package_list;
+ my $package;
+ foreach $package (@{$options{DOPACKAGES}}) {
+ if (! $exclude_package{$package}) {
+ push @package_list, $package;
+ }
+ }
+ @{$options{DOPACKAGES}}=@package_list;
+
+ # Generate EXCLUDE_FIND.
+ $options{EXCLUDE_FIND}='';
+ foreach (@{$options{EXCLUDE}}) {
+ $options{EXCLUDE_FIND}.="-regex .*".quotemeta($_).".* -or ";
+ }
+ $options{EXCLUDE_FIND}=~s/ -or $//;
+
+ # If there are no packages to act on now, it's an error.
+ if (! defined $options{DOPACKAGES} || ! @{$options{DOPACKAGES}}) {
+ error("I have no package to build");
+ }
+
+ # Anything left in @ARGV is options that appeared after a --
+ # These options are added to U_PARAMS, while the non-option
+ # values we collected replace them in @ARGV;
+ $options{U_PARAMS}.=join(' ', @ARGV);
+ @ARGV=@{$options{ARGV}} if exists $options{ARGV};
+
+ return %options;
+}
+
+sub import {
+ # Enable bundling of short command line options.
+ Getopt::Long::config("bundling");
+}
+
+1
diff --git a/Debian/Debhelper/Dh_Lib.pm b/Debian/Debhelper/Dh_Lib.pm
new file mode 100644
index 0000000..915d37a
--- /dev/null
+++ b/Debian/Debhelper/Dh_Lib.pm
@@ -0,0 +1,371 @@
+#!/usr/bin/perl -w
+#
+# Library functions for debhelper programs, perl version.
+#
+# Joey Hess, GPL copyright 1997, 1998.
+
+package Debian::Debhelper::Dh_Lib;
+use strict;
+
+use Exporter;
+use vars qw(@ISA @EXPORT %dh);
+@ISA=qw(Exporter);
+@EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
+ &pkgfile &pkgext &isnative &autoscript &filearray &GetPackages
+ &xargs
+ %dh);
+
+my $max_compat=2;
+
+sub init {
+ # If DH_OPTIONS is set, prepend it @ARGV.
+ if (defined($ENV{DH_OPTIONS})) {
+ unshift @ARGV,split(/\s+/,$ENV{DH_OPTIONS});
+ }
+
+ # Check to see if an argument on the command line starts with a dash.
+ # if so, we need to pass this off to the resource intensive
+ # Getopt::Long, which I'd prefer to avoid loading at all if possible.
+ my $parseopt=undef;
+ my $arg;
+ foreach $arg (@ARGV) {
+ if ($arg=~m/^-/) {
+ $parseopt=1;
+ last;
+ }
+ }
+ if ($parseopt) {
+ eval "use Debian::Debhelper::Dh_Getopt";
+ error($!) if $@;
+ %dh=Debian::Debhelper::Dh_Getopt::parseopts();
+ }
+
+ # Check to see if DH_VERBOSE environment variable was set, if so,
+ # make sure verbose is on.
+ if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
+ $dh{VERBOSE}=1;
+ }
+
+ # Check to see if DH_NO_ACT environment variable was set, if so,
+ # make sure no act mode is on.
+ if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
+ $dh{NO_ACT}=1;
+ }
+
+ # Get the name of the main binary package (first one listed in
+ # debian/control).
+ my @allpackages=GetPackages();
+ $dh{MAINPACKAGE}=$allpackages[0];
+
+ # Check if packages to build have been specified, if not, fall back to
+ # the default, doing them all.
+ if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
+ if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
+ # User specified that all arch (in)dep package be
+ # built, and there are none of that type.
+ error("I have no package to act on");
+ }
+ push @{$dh{DOPACKAGES}},@allpackages;
+ }
+
+ # Check to see if -P was specified. If so, we can only act on a single
+ # package.
+ if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
+ error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
+ }
+
+ # Figure out which package is the first one we were instructed to build.
+ # This package gets special treatement: files and directories specified on
+ # the command line may affect it.
+ $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
+
+ # Split the U_PARAMS up into an array.
+ my $u=$dh{U_PARAMS};
+ undef $dh{U_PARAMS};
+ if (defined $u) {
+ push @{$dh{U_PARAMS}}, split(/\s+/,$u);
+ }
+}
+
+# Escapes out shell metacharacters in a word of shell script.
+sub escape_shell { my $word=shift;
+ # This list is from _Unix in a Nutshell_. (except '#')
+ $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
+ return $word;
+}
+
+# Run a command, and display the command to stdout if verbose mode is on.
+# All commands that modifiy files in $TMP should be ran via this
+# function.
+#
+# Note that this cannot handle complex commands, especially anything
+# involving redirection. Use complex_doit instead.
+sub doit {
+ verbose_print(join(" ",map { escape_shell($_) } @_));
+
+ if (! $dh{NO_ACT}) {
+ system(@_) == 0
+ || error("command returned error code");
+
+ }
+}
+
+# Run a command and display the command to stdout if verbose mode is on.
+# Use doit() if you can, instead of this function, because this function
+# forks a shell. However, this function can handle more complicated stuff
+# like redirection.
+sub complex_doit {
+ verbose_print(join(" ",@_));
+
+ if (! $dh{NO_ACT}) {
+ # The join makes system get a scalar so it forks off a shell.
+ system(join(" ",@_)) == 0
+ || error("command returned error code");
+ }
+}
+
+# Run a command that may have a huge number of arguments, like xargs does.
+# Pass in a reference to an array containing the arguments, and then other
+# parameters that are the command and any parameters that should be passed to
+# it each time.
+sub xargs {
+ my $args=shift;
+
+ # The kernel can accept command lines up to 20k worth of characters.
+ my $command_max=20000;
+
+ # Figure out length of static portion of command.
+ my $static_length=0;
+ foreach (@_) {
+ $static_length+=length($_)+1;
+ }
+
+ my @collect=();
+ my $length=$static_length;
+ foreach (@$args) {
+ if (length($_) + 1 + $static_length > $command_max) {
+ error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
+ }
+ $length+=length($_) + 1;
+ if ($length < $command_max) {
+ push @collect, $_;
+ }
+ else {
+ doit(@_,@collect) if $#collect > -1;
+ @collect=($_);
+ $length=$static_length + length($_) + 1;
+ }
+ }
+ doit(@_,@collect) if $#collect > -1;
+}
+
+# Print something if the verbose flag is on.
+sub verbose_print { my $message=shift;
+ if ($dh{VERBOSE}) {
+ print "\t$message\n";
+ }
+}
+
+# Output an error message and exit.
+sub error { my $message=shift;
+ warning($message);
+ exit 1;
+}
+
+# Output a warning.
+sub warning { my $message=shift;
+ print STDERR basename($0).": $message\n";
+}
+
+# Returns the basename of the argument passed to it.
+sub basename { my $fn=shift;
+ $fn=~s:^.*/(.*?)$:$1:;
+ return $fn;
+}
+
+# Returns the directory name of the argument passed to it.
+sub dirname { my $fn=shift;
+ $fn=~s:^(.*)/.*?$:$1:;
+ return $fn;
+}
+
+# Pass in a number, will return true iff the current compatability level
+# is equal to that number.
+sub compat {
+ my $num=shift;
+
+ my $c=1;
+ if (defined $ENV{DH_COMPAT}) {
+ $c=$ENV{DH_COMPAT};
+ }
+
+ if ($c > $max_compat) {
+ error("Sorry, but $max_compat is the highest compatability level of debhelper currently supported.");
+ }
+
+ return ($c == $num);
+}
+
+# Pass it a name of a binary package, it returns the name of the tmp dir to
+# use, for that package.
+sub tmpdir { my $package=shift;
+ if ($dh{TMPDIR}) {
+ return $dh{TMPDIR};
+ }
+ elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
+ # This is for back-compatability with the debian/tmp tradition.
+ return "debian/tmp";
+ }
+ else {
+ return "debian/$package";
+ }
+}
+
+# Pass this the name of a binary package, and the name of the file wanted
+# for the package, and it will return the actual filename to use. For
+# example if the package is foo, and the file is somefile, it will look for
+# debian/somefile, and if found return that, otherwise, if the package is
+# the main package, it will look for debian/foo, and if found, return that.
+# Failing that, it will return nothing.
+sub pkgfile { my $package=shift; my $filename=shift;
+ if (-f "debian/$package.$filename") {
+ return "debian/$package.$filename";
+ }
+ elsif ($package eq $dh{MAINPACKAGE} && -f "debian/$filename") {
+ return "debian/$filename";
+ }
+ return "";
+}
+
+# Pass it a name of a binary package, it returns the name to prefix to files
+# in debian for this package.
+sub pkgext { my $package=shift;
+ if ($package ne $dh{MAINPACKAGE}) {
+ return "$package.";
+ }
+ return "";
+}
+
+# Returns 1 if the package is a native debian package, null otherwise.
+# As a side effect, sets $dh{VERSION} to the version of this package.
+{
+ # Caches return code so it only needs to run dpkg-parsechangelog once.
+ my %isnative_cache;
+
+ sub isnative { my $package=shift;
+ if (! defined $isnative_cache{$package}) {
+ # Make sure we look at the correct changelog.
+ my $isnative_changelog=pkgfile($package,"changelog");
+ if (! $isnative_changelog) {
+ $isnative_changelog="debian/changelog";
+ }
+
+ # Get the package version.
+ my $version=`dpkg-parsechangelog -l$isnative_changelog`;
+ ($dh{VERSION})=$version=~m/Version: (.*)/m;
+
+ # Is this a native Debian package?
+ if ($dh{VERSION}=~m/.*-/) {
+ $isnative_cache{$package}=0;
+ }
+ else {
+ $isnative_cache{$package}=1;
+ }
+ }
+
+ return $isnative_cache{$package};
+ }
+}
+
+# Automatically add a shell script snippet to a debian script.
+# Only works if the script has #DEBHELPER# in it.
+#
+# Parameters:
+# 1: package
+# 2: script to add to
+# 3: filename of snippet
+# 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
+sub autoscript { my $package=shift; my $script=shift; my $filename=shift; my $sed=shift || "";
+ # This is the file we will append to.
+ my $outfile="debian/".pkgext($package)."$script.debhelper";
+
+ # Figure out what shell script snippet to use.
+ my $infile;
+ if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
+ -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
+ $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
+ }
+ else {
+ if (-e "/usr/share/debhelper/autoscripts/$filename") {
+ $infile="/usr/share/debhelper/autoscripts/$filename";
+ }
+ else {
+ error("/usr/share/debhelper/autoscripts/$filename does not exist");
+ }
+ }
+
+ # TODO: do this in perl, perhaps?
+ complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
+ complex_doit("sed \"$sed\" $infile >> $outfile");
+ complex_doit("echo '# End automatically added section' >> $outfile");
+}
+
+# Reads in the specified file, one word at a time, and returns an array of
+# the result.
+sub filearray { my $file=shift;
+ my @ret;
+ open (DH_FARRAY_IN,"<$file") || error("cannot read $file: $1");
+ while (<DH_FARRAY_IN>) {
+ push @ret,split(' ',$_);
+ }
+ close DH_FARRAY_IN;
+
+ return @ret;
+}
+
+# Returns a list of packages in the control file.
+# Must pass "arch" or "indep" or "same" to specify arch-dependant or
+# -independant or same arch packages. If nothing is specified, returns all
+# packages.
+sub GetPackages { my $type=shift;
+ $type="" if ! defined $type;
+
+ # Look up the build arch if we need to.
+ my$buildarch='';
+ if ($type eq 'same') {
+ $buildarch=`dpkg --print-architecture` || error($!);
+ chomp $buildarch;
+ }
+
+ my $package="";
+ my $arch="";
+ my @list=();
+ open (CONTROL,"<debian/control") ||
+ error("cannot read debian/control: $!\n");
+ while (<CONTROL>) {
+ chomp;
+ s/\s+$//;
+ if (/^Package:\s+(.*)/) {
+ $package=$1;
+ }
+ if (/^Architecture:\s+(.*)/) {
+ $arch=$1;
+ }
+ if (!$_ or eof) { # end of stanza.
+ if ($package &&
+ (($type eq 'indep' && $arch eq 'all') ||
+ ($type eq 'arch' && $arch ne 'all') ||
+ ($type eq 'same' && ($arch eq 'any' || $arch =~ /\b$buildarch\b/)) ||
+ ! $type)) {
+ push @list, $package;
+ $package="";
+ $arch="";
+ }
+ }
+ }
+ close CONTROL;
+
+ return @list;
+}
+
+1