1 files changed, 87 insertions, 0 deletions
diff --git a/dh_installinfo b/dh_installinfo
new file mode 100755
index 00000000..2c3d9e9a
--- /dev/null
+++ b/dh_installinfo
@@ -0,0 +1,87 @@
+#!/usr/bin/perl -w
+
+=head1 NAME
+
+dh_installinfo - install info files
+
+=cut
+
+use strict;
+use Debian::Debhelper::Dh_Lib;
+
+=head1 SYNOPSIS
+
+B<dh_installinfo> [S<I<debhelper options>>] [B<-A>] [S<I<file> ...>]
+
+=head1 DESCRIPTION
+
+B<dh_installinfo> is a debhelper program that is responsible for installing
+info files into F<usr/share/info> in the package build directory.
+
+=head1 FILES
+
+=over 4
+
+=item debian/I<package>.info
+
+List info files to be installed.
+
+=back
+
+=head1 OPTIONS
+
+=over 4
+
+=item B<-A>, B<--all>
+
+Install all files specified by command line parameters in ALL packages
+acted on.
+
+=item I<file> ...
+
+Install these info files into the first package acted on. (Or in
+all packages if B<-A> is specified).
+
+=back
+
+=cut
+
+init();
+
+# PROMISE: DH NOOP WITHOUT info
+
+foreach my $package (@{$dh{DOPACKAGES}}) {
+	my $tmp=tmpdir($package);
+	my $file=pkgfile($package,"info");
+
+	my @info;
+	
+	if ($file) {
+		@info=filearray($file, ".");
+	}
+
+	if (($package eq $dh{FIRSTPACKAGE} || $dh{PARAMS_ALL}) && @ARGV) {
+		push @info, @ARGV;
+	}
+
+	if (@info) {
+		if ( ! -d "$tmp/usr/share/info") {
+			doit("install","-d","$tmp/usr/share/info");
+		}
+		doit("cp",@info,"$tmp/usr/share/info");
+		doit("chmod","-R", "go=rX","$tmp/usr/share/info/");
+		doit("chmod","-R", "u+rw","$tmp/usr/share/info/");
+	}
+}
+
+=head1 SEE ALSO
+
+L<debhelper(7)>
+
+This program is a part of debhelper.
+
+=head1 AUTHOR
+
+Joey Hess <joeyh@debian.org>
+
+=cut