#!/usr/bin/perl -w

=head1 NAME

dh_installcron - install cron scripts into etc/cron.*

=cut

use strict;
use Debian::Debhelper::Dh_Lib;

=head1 SYNOPSIS

B<dh_installcron> [S<B<debhelper options>>]

=head1 DESCRIPTION

dh_installcron is a debhelper program that is responsible for installing
cron scripts into etc/cron.*/ in package build directories. The files
debian/package.cron.daily, debian/package.cron.weekly,
debian/package.cron.monthly, and debian/package.cron.d are installed.

=cut

init();

foreach my $package (@{$dh{DOPACKAGES}}) {
	my $tmp=tmpdir($package);
	foreach my $type (qw{daily weekly monthly}) {
		my $cron=pkgfile($package,"cron.$type");
		if ($cron) {
			if (! -d "$tmp/etc/cron.$type") {
				doit("install","-o",0,"-g",0,"-d","$tmp/etc/cron.$type");
			}
			doit("install",$cron,"$tmp/etc/cron.$type/$package");
		}
	}
	# Seperate because this needs to be mode 644.
	my $cron=pkgfile($package,"cron.d");
	if ($cron) {
		if (! -d "$tmp/etc/cron.d") {
			doit("install","-o",0,"-g",0,"-d","$tmp/etc/cron.d");
		}	
		doit("install","-m",644,$cron,"$tmp/etc/cron.d/$package");
	}
}

=head1 SEE ALSO

L<debhelper(1)>

This program is a part of debhelper.

=head1 AUTHOR

Joey Hess <joeyh@debian.org>

=cut