#!/usr/bin/perl -w
#
# Reads debian/info, installs all files listed there into /usr/share/info
# and puts appropriate commands into the postinst.

use strict;
use Debian::Debhelper::Dh_Lib;
init();

foreach my $package (@{$dh{DOPACKAGES}}) {
	my $tmp=tmpdir($package);
	my $file=pkgfile($package,"info");

	my @info;
	
	if ($file) {
		@info=filearray($file, ".");
	}

	if (($package eq $dh{FIRSTPACKAGE} || $dh{PARAMS_ALL}) && @ARGV) {
		push @info, @ARGV;
	}

	if (@info) {
		if ( ! -d "$tmp/usr/share/info") {
			doit("install","-d","$tmp/usr/share/info");
		}
		doit("cp",@info,"$tmp/usr/share/info");
		doit("chmod","-R", "go=rX","$tmp/usr/share/info/");
		doit("chmod","-R", "u+rw","$tmp/usr/share/info/");
	}

	foreach $file (@info) {
		# Only register with install-info if this is a head file in
		# a tree of info files.
		if ($file !~ /-\d+$/ && ! $dh{NOSCRIPTS}) {
			# Figure out what section this file goes in.
			my $section='';
			open (IN, "<$file") || die "$file: $!";
			while (<IN>) {
				if (/INFO-DIR-SECTION\s+(.*)/) {
					$section=$1;
					last;
				}
			}
			close IN;
			
			my $fn="/usr/share/info/".basename($file);
			
			if ($section ne '') {
				$section=~s:/:\\/:g; # allow / in section.
				autoscript($package,"postinst","postinst-info",
					"s/#SECTION#/$section/g;s:#FILE#:$fn:");
			}
			else {
				autoscript($package,"postinst","postinst-info-nosection",
					"s:#FILE#:$fn:");
			}
			autoscript($package,"prerm","prerm-info", "s:#FILE#:$fn:");
		}
	}
}