summaryrefslogtreecommitdiff
path: root/Debian/Debhelper/Buildsystem/perl_build.pm
blob: 74106d9bf3cd0a85a071570ae64f21bb1eb97a04 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
# A buildsystem plugin for handling Perl Build based projects.
#
# Copyright: © 2008-2009 Joey Hess
#            © 2008-2009 Modestas Vainius
# License: GPL-2+

package Debian::Debhelper::Buildsystem::perl_build;

use strict;
use Debian::Debhelper::Dh_Lib;
use Debian::Debhelper::Dh_Buildsystem_Bases;
use base 'Debian::Debhelper::Dh_Buildsystem_Basic';

sub DESCRIPTION {
	"support for building Perl Build.PL based packages (in-source only)"
}

sub is_buildable {
	my ($self, $action) = @_;
	my $ret = (-e "Build.PL");
	if ($action ne "configure") {
		$ret &= (-e "Build");
	}
	return $ret;
}

sub invoke_impl {
	my $self=shift;
	$ENV{MODULEBUILDRC} = "/dev/null";
	return $self->SUPER::invoke_impl(@_);
}

sub new {
	my $cls=shift;
	my $self= $cls->SUPER::new(@_);
	$self->enforce_in_source_building();
	return $self;
}

sub configure_impl {
	my $self=shift;
	$ENV{PERL_MM_USE_DEFAULT}=1; # Module::Build can also use this.
	doit("perl", "Build.PL", "installdirs=vendor", @_);
}

sub build_impl {
	my $self=shift;
	doit("perl", "Build", @_);
}

sub test_impl {
	my $self=shift;
	doit(qw/perl Build test/, @_);
}

sub install_impl {
	my $self=shift;
	my $destdir=shift;
	doit("perl", "Build", "install", "destdir=$destdir", "create_packlist=0", @_);
}

sub clean_impl {
	my $self=shift;
	doit("perl", "Build", "--allow_mb_mismatch", 1, "distclean", @_);
}

1;