summaryrefslogtreecommitdiff
path: root/Debian/Debhelper/Buildsystem/perl_build.pm
blob: e00a7eb0bf93721b926d3f5f9af3f1b1725f6fb9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
# A buildsystem plugin for handling Perl Build based projects.
#
# Copyright: © 2008-2009 Joey Hess
#            © 2008-2009 Modestas Vainius
# License: GPL-2+

package Debian::Debhelper::Buildsystem::perl_build;

use strict;
use Debian::Debhelper::Dh_Lib;
use base 'Debian::Debhelper::Buildsystem';

sub DESCRIPTION {
	"support for building Perl Build.PL based packages (in-source only)"
}

sub check_auto_buildable {
	my ($this, $action) = @_;

	# Handles everything
	my $ret = -e "Build.PL";
	if ($action ne "configure") {
		$ret &&= -e "Build";
	}
	return $ret;
}

sub do_perl {
	my $this=shift;
	$ENV{MODULEBUILDRC} = "/dev/null";
	doit("perl", @_);
}

sub new {
	my $class=shift;
	my $this= $class->SUPER::new(@_);
	$this->enforce_in_source_building();
	return $this;
}

sub configure {
	my $this=shift;
	$ENV{PERL_MM_USE_DEFAULT}=1;
	$this->do_perl("Build.PL", "installdirs=vendor", @_);
}

sub build {
	my $this=shift;
	$this->do_perl("Build", @_);
}

sub test {
	my $this=shift;
	$this->do_perl("Build", "test", @_);
}

sub install {
	my $this=shift;
	my $destdir=shift;
	$this->do_perl("Build", "install", "destdir=$destdir", "create_packlist=0", @_);
}

sub clean {
	my $this=shift;
	$this->do_perl("Build", "--allow_mb_mismatch", 1, "distclean", @_);
}

1;