summaryrefslogtreecommitdiff
path: root/Debian/Debhelper/Buildsystem/perl_makemaker.pm
blob: 2957016668c27764a564228e2110adc1fc1c1b16 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
# A buildsystem plugin for handling Perl MakeMaker based projects.
#
# Copyright: © 2008-2009 Joey Hess
#            © 2008-2009 Modestas Vainius
# License: GPL-2+

package Debian::Debhelper::Buildsystem::perl_makemaker;

use strict;
use Debian::Debhelper::Dh_Lib;
use base 'Debian::Debhelper::Buildsystem::makefile';

sub DESCRIPTION {
	"support for building Perl MakeMaker based packages (in-source only)"
}

sub check_auto_buildable {
	my $self=shift;
	my ($action)=@_;

	# Handles configure, install; the rest - next class
	if ($action eq "install") {
		return -e "Makefile.PL";
	}
	# XXX JEH why test for configure here? If building or cleaning, and
	# a Makefile.PL exists, we know this class can handle those
	# actions -- it does so by inheriting from the makefile class.
	# XXX MDX Yes. But that's again different behaviour from current
	#         (see comment in autotools.mk). Your call.
	elsif ($action eq "configure") {
		return -e "Makefile.PL";
	}
	else {
		return 0;
	}
}

sub new {
	my $cls=shift;
	my $self=$cls->SUPER::new(@_);
	$self->enforce_in_source_building();
	return $self;
}

sub configure {
	my $self=shift;
	# If set to a true value then MakeMaker's prompt function will
	# # always return the default without waiting for user input.
	$ENV{PERL_MM_USE_DEFAULT}=1;
	doit("perl", "Makefile.PL", "INSTALLDIRS=vendor", @_);
}

sub install {
	my $self=shift;
	my $destdir=shift;
	$self->SUPER::install($destdir, "PREFIX=/usr", @_);
}

1;