summaryrefslogtreecommitdiff
path: root/dh_gencontrol
blob: 99923cf4465c48f0341dce26ea2f8cabe923efe3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
#!/usr/bin/perl -w

=head1 NAME

dh_gencontrol - generate and install control file

=cut

use strict;
use Debian::Debhelper::Dh_Lib;

=head1 SYNOPSIS

  dh_gencontrol [debhelper options] [-uparams] [-- params]

=head1 DESCRIPTION

dh_gencontrol is a debhelper program that is responsible for generating
control files, and installing them into the DEBIAN directory with the
proper permissions.

This program is merely a wrapper around L<dpkg-gencontrol(1)>, which calls
it once for each package being acted on, and passes in some additional
useful flags including "-isp". 

Note that L<dpkg-gencontrol(1)> expands certian substirution variables
when generating the control file (for details, see its man page). Those
variables are typically generated by L<dh_shlibdeps(1)> and like programs.
However, if you want to specify some of your own manually, you may do so,
by creating files named debian/package.substvars (where package is the
package these variables apply to). The files should be of the same form
output by L<dpkg-shlibdeps(1)>

=head1 OPTIONS

=over 4

=item B<-u>I<params>, B<--dpkg-gencontrol-params>I<params>

=item B<--> I<params>

Pass "params" to L<dpkg-gencontrol(1)>.

=back

=cut

init();

foreach my $package (@{$dh{DOPACKAGES}}) {
	my $tmp=tmpdir($package);
	my $ext=pkgext($package);
	
	my $changelog=pkgfile($package,'changelog');
	if (! $changelog) {
		$changelog='debian/changelog';
	}

	if ( ! -d "$tmp/DEBIAN" ) {
		doit("install","-o",0,"-g",0,"-d","$tmp/DEBIAN");
	}

	# Merge in user-specified substvars file with debhelper generated
	# one.
	my $substvars=pkgfile($package,"substvars");
	if ($substvars) {
		complex_doit("cat $substvars >> debian/${ext}substvars.debhelper");
	}

	# Generate and install control file.
	doit("dpkg-gencontrol","-l$changelog","-isp","-p$package",
		     "-Tdebian/${ext}substvars.debhelper",
		     "-P$tmp",@{$dh{U_PARAMS}});

	# This chmod is only necessary if the user sets the umask to
	# something odd.
	doit("chmod","644","$tmp/DEBIAN/control");
	
	doit("chown","0.0","$tmp/DEBIAN/control");
}

=head1 SEE ALSO

L<debhelper(1)>

This program is a part of debhelper.

=head1 AUTHOR

Joey Hess <joeyh@debian.org>

=cut