1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
|
#!/usr/bin/perl -w
=head1 NAME
dh_install - install files into package build directories
=cut
use strict;
use File::Find;
use Debian::Debhelper::Dh_Lib;
=head1 SYNOPSIS
B<dh_install> [B<-X>I<item>] [B<--sutodest>] [B<--list-missing>] [S<I<debhelper options>>] [S<I<file [...] dest>>]
=head1 DESCRIPTION
dh_install is a debhelper program that handles installing files into package
build directories. There are many dh_install* commands that handle installing
specific types of files such as documentation, examples, man pages, and so on,
and they should be used when possible as they often have extra intelligence for
those particular tasks. dh_install, then, is useful for installing everything
else, for which no particular intelligence is needed. It is a replacement for
the old dh_movefiles command.
Files named debian/package.install list the files to install into each
package and where they should be installed to. The format is a set of
lines, where each line lists a file or files to install, and at the end of
the line tells the directory it should be installed in. The name of the
files (or directories) to install should be given relative to the current
directory, while the installation directory is given relative to the
package build directory. You may use wildcards in the names of the files to
install (in v3 mode and above).
This program may be used in one of two ways. If you just have a file or two
that the upstream Makefile does not install for you, you can run dh_install
on them to move them into place. On the other hand, maybe you have a large
package that builds multiple binary packages. You can use the upstream Makefile
to install it all into debian/tmp, and then use dh_install to copy
directories and files from there into the proper package build directories.
=head1 OPTIONS
=over 4
=item B<-Xitem>, B<--exclude=item>
Exclude files that contain "item" anywhere in their filename from
being installed.
=item B<--autodest>
Guess as the destination directory to install things to. If this is
specified, you should not list destination directories in
debian/package.install files or on the command line. Instead, dh_install
will guess as follows:
Strip off debian/tmp from the front of the filename, of it is present, and
install into the dirname of the filename. So if the filename is
debian/tmp/usr/bin, then that directory will be copied to
debian/package/usr/. If the filename is debian/tmp/etc/passwd, it will be
copied to debian/package/etc/.
Note that if you list only a filename on a line by itself in a
debian/package.install file, with no explicit destination, then dh_install
will automatically guess the destination even if this flag is not set.
=item B<--list-missing>
This option makes dh_install keep track of the files it installs, and then at
the end, compare that list with the files in debian/tmp. If any of the files
(and symlinks) in debian/tmp were not installed to somewhere, it will
warn on stderr about that.
This may be useful if you have a large package and want to make sure that
you don't miss installing newly added files in new upstream releases.
Note that files that are excluded from being moved via the -X option are not
warned about.
=item B<--sourcedir=dir>
Makes all source files relative to "dir". If this is specified, it is akin
to all the source files having "dir" prepended to them. By default, "dir"
is '.'.
To make dh_install behave like the old dh_movefiles, move your
package.files file to package.install and call dh_install with
"--sourcedir=debian/tmp" appended to the command. This will
approximate dh_movefiles behaviour, except it will copy files instead
of moving them.
=item I<file [...] dest>
Lists files (or directories) to install and where to install them to.
The files will be installed into the first package dh_install acts on.
=back
=cut
init();
my @installed;
foreach my $package (@{$dh{DOPACKAGES}}) {
my $tmp=tmpdir($package);
my $file=pkgfile($package,"install");
my $srcdir = '.';
my @install;
if ($file) {
@install=filedoublearray($file); # no globbing yet
}
$srcdir = $dh{SOURCEDIR}."/" if defined $dh{SOURCEDIR};
if (($package eq $dh{FIRSTPACKAGE} || $dh{PARAMS_ALL}) && @ARGV) {
push @install, [@ARGV];
}
# Support for -X flag.
my $exclude = '';
if ($dh{EXCLUDE_FIND}) {
$exclude = '-and ! \( '.$dh{EXCLUDE_FIND}.' \)';
}
foreach my $set (@install) {
my $dest;
if (! defined $dh{AUTODEST} && @$set > 1) {
$dest=pop @$set;
}
# glob now, relative to srcdir
foreach my $src (map { glob "$srcdir/$_" } @$set) {
next if excludefile($src);
if (! defined $dest) {
# Guess at destination directory.
$dest=$src;
$dest=~s/^(.*\/)?debian\/tmp//;
$dest=dirname($dest);
}
# Make sure the destination directory exists.
if (! -e "$tmp/$dest") {
doit("install","-d","$tmp/$dest");
}
# Keep track of what's installed.
if ($dh{LIST_MISSING}) {
# Kill any extra slashes. Makes the
# @installed stuff more robust.
$src=~y:/:/:s;
$src=~s:/+$::;
push @installed, "\Q$src\E\/.*|\Q$src\E";
}
if (-d $src && $exclude) {
my ($dir_basename) = basename($src);
# Pity there's no cp --exclude ..
my $pwd=`pwd`;
chomp $pwd;
complex_doit("cd $src/.. && find $dir_basename \\( -type f -or -type l \\) $exclude -exec cp --parents -dp {} $pwd/$tmp/$dest/ \\;");
}
else {
doit("cp", "-a", $src, "$tmp/$dest/");
}
}
}
}
if ($dh{LIST_MISSING}) {
my @missing;
my $installed=join("|", @installed);
$installed=qr{^$installed$};
find(sub {
-f || -l || return;
$_="$File::Find::dir/$_";
push @missing, $_ unless /$installed/;
}, './debian/tmp');
if (@missing) {
warning "$_ not installed" foreach @missing;
}
}
=head1 SEE ALSO
L<debhelper(1)>
This program is a part of debhelper.
=head1 AUTHOR
Joey Hess <joeyh@debian.org>
=cut
|
