summaryrefslogtreecommitdiff
path: root/dh_installdeb
blob: 1f02edf45b25d163dfc270efd061159f87a2681e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
#!/usr/bin/perl -w

=head1 NAME

dh_installdeb - install files into the DEBIAN directory

=cut

use strict;
use Debian::Debhelper::Dh_Lib;

=head1 SYNOPSIS

B<dh_installdeb> [S<I<debhelper options>>]

=head1 DESCRIPTION

B<dh_installdeb> is a debhelper program that is responsible for installing
files into the F<DEBIAN> directories in package build directories with the
correct permissions.

=head1 FILES

=over 4

=item I<package>.postinst

=item I<package>.preinst

=item I<package>.postrm

=item I<package>.prerm

These maintainer scripts are installed into the F<DEBIAN> directory.

Inside the scripts, the token B<#DEBHELPER#> is replaced with
shell script snippets generated by other debhelper commands.

=item I<package>.triggers

=item I<package>.shlibs

These control files are installed into the F<DEBIAN> directory.

=item I<package>.conffiles

This control file will be installed into the F<DEBIAN> directory.

In v3 compatibility mode and higher, all files in the F<etc/> directory in a
package will automatically be flagged as conffiles by this program, so
there is no need to list them manually here.

=item I<package>.maintscript

Lines in this file correspond to L<dpkg-maintscript-helper(1)> commands and
parameters.  Any shell metacharacters will be escaped, so arbitrary shell
code cannot be inserted here.  For example, a line such as C<mv_conffile
/etc/oldconffile /etc/newconffile> will insert maintainer script snippets
into all maintainer scripts sufficient to move that conffile.

=back

=cut

init();

# dpkg-maintscript-helper commands with their associated dpkg pre-dependency
# versions.
my %maintscript_predeps = (
	"rm_conffile" => "",
	"mv_conffile" => "",
	"symlink_to_dir" => "1.17.5",
	"dir_to_symlink" => "1.17.5",
);

foreach my $package (@{$dh{DOPACKAGES}}) {
	my $tmp=tmpdir($package);

	if (! -d "$tmp/DEBIAN") {
		doit("install","-o",0,"-g",0,"-d","$tmp/DEBIAN");
	}

	if (is_udeb($package)) {
		# For udebs, only do the postinst, and no #DEBHELPER#.
		# Udebs also support menutest and isinstallable scripts.
		foreach my $script (qw{postinst menutest isinstallable}) {
			my $f=pkgfile($package,$script);
			if ($f) {
				doit("install", "-o", 0, "-g", 0, "-m", 755, 
				     $f, "$tmp/DEBIAN/$script");
			}
		}

		# stop here for udebs
		next;
	}
	
	my $maintscriptfile=pkgfile($package, "maintscript");
	if ($maintscriptfile) {
		foreach my $line (filedoublearray($maintscriptfile)) {
			my $cmd=$line->[0];
			error("unknown dpkg-maintscript-helper command: $cmd")
				unless exists $maintscript_predeps{$cmd};
			addsubstvar($package, "misc:Pre-Depends", "dpkg",
				    ">= $maintscript_predeps{$cmd}")
			    	if length $maintscript_predeps{$cmd};
			my $params=escape_shell(@$line);
			foreach my $script (qw{postinst preinst prerm postrm}) {
				autoscript($package, $script, "maintscript-helper",
					   "s!#PARAMS#!$params!g");
			}
		}
	}

	# Install debian scripts.
	foreach my $script (qw{postinst preinst prerm postrm}) {
		debhelper_script_subst($package, $script);
	}

	# Install non-executable files
	foreach my $file (qw{shlibs conffiles triggers}) {
		my $f=pkgfile($package,$file);
		if ($f) {
			doit("install","-o",0,"-g",0,"-m",644,"-p",$f,"$tmp/DEBIAN/$file");
		}
	}

	# Automatic conffiles registration: If it is in /etc, it is a
	# conffile.
	if (! compat(2) && -d "$tmp/etc") {
		complex_doit("find $tmp/etc -type f -printf '/etc/%P\n' >> $tmp/DEBIAN/conffiles");
		# Anything found?
		if (-z "$tmp/DEBIAN/conffiles") {
			doit("rm", "-f", "$tmp/DEBIAN/conffiles");
		}
		else {
			doit("chmod", 644, "$tmp/DEBIAN/conffiles");
		}
	}
}

=head1 SEE ALSO

L<debhelper(7)>

This program is a part of debhelper.

=head1 AUTHOR

Joey Hess <joeyh@debian.org>

=cut