summaryrefslogtreecommitdiff
path: root/dh_installdebconf
blob: ebf6a13123090c0943bf5e24711fb327fba30c8d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
#!/usr/bin/perl -w

=head1 NAME

dh_installdebconf - install files used by debconf in package build directories

=cut

use strict;
use Debian::Debhelper::Dh_Lib;

=head1 SYNOPSIS

B<dh_installdebconf> [S<I<debhelper options>>] [B<-n>] [S<B<--> I<params>>]

=head1 DESCRIPTION

dh_installdebconf is a debhelper program that is responsible for installing
files used by the debconf package into package build directories.

It also automatically generates the postrm commands needed to
interface with debconf. See L<dh_installdeb(1)> for an explanation of how
that works.

Files named debian/package.config and debian/package.templates are
installed into the DEBIAN directory in the package build directory.

Note that if you use debconf, your package probably needs to depend on it
(it will be added to ${misc:Depends} by this program).

Note that for your config script to be called by dpkg, your postinst
needs to source debconf's confmodule. dh_installdebconf does not
install this statement into postinst automatically as it it too hard to
do it right.

=head1 LOCALIZED TEMPLATE FILES

Debconf also supports localized template files, and this program has some
support to aid is working with them. It is best to keep the translations in
.po files under debian/po, and merge them only at build time. See 
L<po2debconf(1)> and L<debconf-getlang(1)> for details.

This program will look to see if you have a debian/po directory and if so will
automatically call L<po2debconf(1)> to generate a merged templates file. Or 
if you have debian/templates.ll files, it will use the older 
L<debconf-mergetemplate(1)> program to merge those together.

Note that if your package has a debian/po directory it should build-depend on po-debconf.

For example, if you have a German translation,
strings from debian/po/de.po are merged with debian/package.templates.

=head1 OPTIONS

=over 4

=item B<-n>, B<--noscripts>

Do not modify postrm script.

=item B<--> I<params>

Pass the params to po2debconf, if it is run or debconf-mergetemplate, if it
is run.

=back

=cut

init();

my @extraparams;
if (defined($dh{U_PARAMS})) {
	@extraparams=@{$dh{U_PARAMS}};
}

foreach my $package (@{$dh{DOPACKAGES}}) {
	my $tmp=tmpdir($package);
	my $config=pkgfile($package,"config");
	my $templates=pkgfile($package,"templates");

	if (! -d "$tmp/DEBIAN") {
		doit("install","-o",0,"-g",0,"-d","$tmp/DEBIAN");
	}

	if (! is_udeb($package) && $config ne '') {
		doit("install", "-o", 0, "-g", 0, "-m", 755, "-p",
		     $config, "$tmp/DEBIAN/config");
	}
	
	if ($templates ne '') {
		# Are there old-style translated templates?
		my @trans=(glob("$templates.??"), glob("$templates.??_??"));

		umask(0022); # since I do a redirect below
		
		# Look for po directory.
		if (-d "debian/po") {
			if (@trans) {
				warning "ignoring debian/templates.ll files in favour of debian/po directory";
			}
			complex_doit("po2debconf @extraparams $templates > $tmp/DEBIAN/templates");
		}
		elsif (@trans) {
			complex_doit("debconf-mergetemplate --drop-old-templates @extraparams @trans $templates > $tmp/DEBIAN/templates");
			chmod 0644, "$tmp/DEBIAN/templates";
			chown 0, 0, "$tmp/DEBIAN/templates";
		}
		else {
			doit("install", "-o", 0, "-g", 0, "-m", 644, "-p",
			     $templates, "$tmp/DEBIAN/templates");
		}
	}

	# I'm going with debconf 0.5 because it was the first
	# "modern" one.
	my $debconfdep="debconf (>= 0.5) | debconf-2.0";
	if ($config ne '' || $templates ne '') {
		addsubstvar($package, "misc:Depends", $debconfdep);
	}
	else {
		addsubstvar($package, "misc:Depends", $debconfdep, undef, 1); # remove
	}
	
	if (($config ne '' || $templates ne '') && ! $dh{NOSCRIPTS}) {
		autoscript($package,"postrm","postrm-debconf");
	}
}

=head1 SEE ALSO

L<debhelper(7)>

This program is a part of debhelper.

=head1 AUTHOR

Joey Hess <joeyh@debian.org>

=cut