summaryrefslogtreecommitdiff
path: root/dh_installlogcheck
blob: 0821f1d5e0fba36eedf18bf23a938be89f83fc5c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
#!/usr/bin/perl -w

=head1 NAME

dh_installlogcheck - install logcheck rulefiles into etc/logcheck/

=cut

use strict;
use Debian::Debhelper::Dh_Lib;

=head1 SYNOPSIS

B<dh_installlogcheck> [S<I<debhelper options>>]

=head1 DESCRIPTION

B<dh_installlogcheck> is a debhelper program that is responsible for
installing logcheck rule files.

=head1 FILES

=over 4

=item debian/I<package>.logcheck.cracking

=item debian/I<package>.logcheck.violations

=item debian/I<package>.logcheck.violations.ignore

=item debian/I<package>.logcheck.ignore.workstation

=item debian/I<package>.logcheck.ignore.server

=item debian/I<package>.logcheck.ignore.paranoid

Each of these files, if present, are installed into corresponding
subdirectories of F<etc/logcheck/> in package build directories.

=back

=head1 OPTIONS

=over 4

=item B<--name=>I<name>

Look for files named F<debian/package.name.logcheck.*> and install
them into the corresponding subdirectories of F<etc/logcheck/>, but
use the specified name instead of that of the package.

=back

=cut

init();

# PROMISE: DH NOOP WITHOUT logcheck.cracking logcheck.violations logcheck.violations.ignore logcheck.ignore.workstation logcheck.ignore.server logcheck.ignore.paranoid

foreach my $package (@{$dh{DOPACKAGES}}) {
	my $tmp=tmpdir($package);

	foreach my $type (qw{ignore.d.workstation ignore.d.server
	                     ignore.d.paranoid cracking.d
                             violations.d violations.ignore.d}) {
		my $typenod=$type;
		$typenod=~s/\.d//;
		my $logcheck=pkgfile($package,"logcheck.$typenod");
		if ($logcheck) {
			if (! -d "$tmp/etc/logcheck/$type") {
				doit("install","-o",0,"-g",0,"-d","$tmp/etc/logcheck/$type");
			}
			my $packagenodot=pkgfilename($package); # run-parts..
			$packagenodot=~s/\./_/g;
			doit("install","-m","0644",$logcheck,"$tmp/etc/logcheck/$type/$packagenodot");
		}
	}
}

=head1 SEE ALSO

L<debhelper(7)>

This program is a part of debhelper.
    
=head1 AUTHOR

Jon Middleton <jjm@debian.org>

=cut