summaryrefslogtreecommitdiff
path: root/dgit
blob: a2e148898c2b7d22ce532ffeeab0c3f4eb4f31ef (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
#!/usr/bin/perl -w
# dgit
# Integration between git and Debian-style archives
#
# Copyright (C)2013 Ian Jackson
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

use strict;

use IO::Handle;
use Data::Dumper;
use LWP::UserAgent;
use Dpkg::Control::Hash;
use File::Path;
use POSIX;

open DEBUG, ">&STDERR" or die $!;

our $mirror = 'http://mirror.relativity.greenend.org.uk/mirror/debian-ftp/';
our $suite = 'sid';
our $package;

our $sign = 1;
our $nopush = 0;

our $aliothname = 'iwj@git.debian.org';
our $aliothpath = '/git/dgit-test';
our $alioth_git = "git+ssh://$aliothname/$aliothpath";
our $alioth_sshtestbodge = [$aliothname,$aliothpath];

our (@dget_opts) = qw(-u);
our (@git_tag_opts);
our (@gpg_opts);

our $remotename = 'dgit';
our $ourdscfield = 'Vcs-git-master';

sub uploadbranch () { return "dgit/$suite"; }
sub lref ($) { return "refs/heads/$_[0]"; }
sub rref ($) { return "refs/remotes/$remotename/$_[0]"; }
sub debiantag ($) { return "debian/$_[0]"; }

our $ua;

sub url_get {
    if (!$ua) {
	$ua = LWP::UserAgent->new();
	$ua->env_proxy;
    }
    print DEBUG "fetching @_...\n";
    my $r = $ua->get(@_) or die $!;
    die "$_[0]: ".$r->status_line."; failed.\n" unless $r->is_success;
    return $r->decoded_content();
}

our ($dscdata,$dscurl,$dsc);

sub runcmd {
    $!=0; $?=0;
    die "@_ $! $?" if system @_;
}

sub cmdoutput {
    open P, "-|", @_ or die $!;
    my $d;
    $!=0; $?=0;
    { local $/ = undef; $d = <P>; }
    die if P->error;
    close P or die "@_ $? $!";
    chomp $d;
    return $d;
}

sub parsecontrol {
    my $c = Dpkg::Control::Hash->new();
    $c->load(@_) or return undef;
    return $c;
}

sub parsechangelog {
    my $c = Dpkg::Control::Hash->new();
    my $p = new IO::Handle;
    open $p, '-|', qw(dpkg-parsechangelog) or die $!;
    $c->parse($p);
    $?=0; $!=0; close $p or die "$! $?";
    return $c;
}

sub get_archive_dsc () {
    my $rmad = cmdoutput qw(rmadison -asource),"-s$suite",$package;
    $rmad =~ m/^ \s*( [^ \t|]+ )\s* \|
                 \s*( [^ \t|]+ )\s* \|
                 \s*( [^ \t|]+ )\s* \|
                 \s*( [^ \t|]+ )\s* /x or die "$rmad $?";
    $1 eq $package or die "$rmad $package ?";
    my $vsn = $2;
    $3 eq $suite or die "$rmad $suite ?";
    $4 eq 'source' or die "$rmad ?";
    # fixme it does not show us the component ?
    my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
    $dscurl = "$mirror/pool/main/$prefix/$package/${package}_$vsn.dsc";
#print DEBUG Dumper($pdodata, $&, $dscurl);
    $dscdata = url_get($dscurl);
    my $dscfh = new IO::File \$dscdata, '<' or die $!;
#print DEBUG Dumper($dscdata, $dscfh);
    $dsc = Dpkg::Control::Hash->new(allow_pgp=>1);
    $dsc->parse($dscfh, 'dsc') or die "parsing of $dscurl failed\n";
#print DEBUG Dumper($dsc);
    my $fmt = $dsc->{Format};
    die "unsupported format $fmt, sorry\n" unless $fmt eq '1.0';
}

sub check_for_git () {
    # returns 0 or 1
    my $cmd= 
	"ssh $alioth_sshtestbodge->[0] '".
	" set -e; cd /git/dgit-test;".
	" if test -d $package.git; then echo 1; else echo 0; fi".
	"'";
    #print DEBUG "$cmd\n";
    open P, "$cmd |" or die $!;
    $!=0; $?=0;
    my $r = <P>; close P;
#print STDERR ">$r<\n";
    die "$r $! $?" unless $r =~ m/^[01]$/;
    return $r+0;
}

our ($dsc_hash,$upload_hash);

our $ud = '.git/dgit/unpack';

sub prep_ud () {
    rmtree($ud);
    mkpath '.git/dgit';
    mkdir $ud or die $!;
}

sub mktree_in_ud_from_only_subdir () {
    # changes into the subdir
    my (@dirs) = <*/.>;
    die unless @dirs==1;
    $dirs[0] =~ m#^([^/]+)/\.$# or die;
    my $dir = $1;
    chdir $dir or die "$dir $!";
    die if stat '.git';
    die $! unless $!==&ENOENT;
    runcmd qw(git init -q);
    rmtree('.git/objects');
    symlink '../../../../objects','.git/objects' or die $!;
    runcmd qw(git add -Af);
    my $tree = cmdoutput qw(git write-tree);
    chomp $tree; $tree =~ m/^\w+$/ or die "$tree ?";
    return ($tree,$dir);
}

sub dsc_files () {
    map {
	m/^\w+ \d+ (\S+)$/ or die "$_ ?";
	$1;
    } grep m/\S/, split /\n/, ($dsc->{'Checksums-Sha256'} || $dsc->{Files});
}

sub is_orig_file ($) {
    local ($_) = @_;
    m/\.orig\.tar\.\w+$/;
}

sub generate_commit_from_dsc () {
    prep_ud();
    chdir $ud or die $!;
    my @files;
    foreach my $f (dsc_files()) {
	die if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
	push @files, $f;
	link "../../../$f", $f
	    or $!==&ENOENT
	    or die "$f $!";
    }
    runcmd qw(dget), @dget_opts, qw(--), $dscurl;
    foreach my $f (grep { is_orig_file($_) } @files) {
	link $f, "../../../$f"
	    or $!==&EEXIST
	    or die "$f $!";
    }
    my ($tree,$dir) = mktree_in_ud_from_only_subdir();
    runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
    my $clogp = parsecontrol('../changelog.tmp','changelog') or die;
    my $date = cmdoutput qw(date), '+%s %z', qw(-d),$clogp->{Date};
    my $author = $clogp->{Maintainer};
    $author =~ s#,.*##ms;
    my $authline = "$author $date";
    $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or die $authline;
    open C, ">../commit.tmp" or die $!;
    print C "tree $tree\n" or die $!;
    print C "parent $upload_hash\n" or die $! if defined $upload_hash;
    print C <<END or die $!;
author $authline
committer $authline

$clogp->{Changes}

# imported by dgit from the archive
END
    close C or die $!;
    print "synthesised git commit from .dsc $clogp->{Version}\n";
    my $commithash = cmdoutput qw(git hash-object -w -t commit ../commit.tmp);
    chdir '../../../..' or die $!;
    cmdoutput qw(git update-ref -m),"dgit synthesise $clogp->{Version}",
              'DGIT_ARCHIVE', $commithash;
    cmdoutput qw(git log -n2), $commithash;
    # ... gives git a chance to complain if our commit is malformed
    my $outputhash = $commithash;
    if (defined $upload_hash) {
	chdir "$ud/$dir" or die $!;
	runcmd qw(git reset --hard), $upload_hash;
	runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
	my $oldclogp = Dpkg::Control::Hash->new();
	$oldclogp->parse('../changelogold.tmp','previous changelog') or die;
	my $vcmp =
	    version_compare_string($oldclogp->{Version}, $clogp->{Version});
	if ($vcmp < 0) {
	    # git upload/ is earlier vsn than archive, use archive
	} elsif ($vcmp >= 0) {
	    print STDERR <<END or die $!;
Version actually in archive:    $clogp->{Version} (older)
Last allegedly pushed/uploaded: $oldclogp->{Version} (newer or same)
Perhaps the upload is stuck in incoming.  Using the version from git.
END
	} else {
	    die "version in archive is same as version in git".
		" to-be-uploaded (upload/) branch but archive".
		" version hash no commit hash?!\n";
        }
	chdir '../../../..' or die $!;
    }
    rmtree($ud);
    return $outputhash;
}

sub ensure_we_have_orig () {
    foreach my $f (dsc_files()) {
	next unless is_orig_file($f);
	if (stat "../$f") {
	    die "$f ?" unless -f _;
	} else {
	    die "$f $!" unless $!==&ENOENT;
	}
	my $origurl = $dscurl;
	$origurl =~ s{/[^/]+$}{};
	$origurl .= "/$f";
	die "$f ?" unless $f =~ m/^${package}_/;
	die "$f ?" if $f =~ m#/#;
	runcmd qw(sh -ec),'cd ..; exec dget -- "$1"','x',$origurl;
    }
}

sub rev_parse ($) {
    return cmdoutput qw(git rev-parse --), "$_[0]~0";
}

sub is_fast_fwd ($$) {
    my ($ancestor,$child) = @_;
    my $mb = cmdoutput qw(git merge-base), $dsc_hash, $upload_hash;
    return rev_parse($mb) eq rev_parse($ancestor);
}

sub fetch_from_archive () {
    # ensures that rref(uploadbranch()) is what is actually in the archive,
    #  one way or another
    my $upload_ref = rref(uploadbranch());
    $!=0; $upload_hash = `git show-ref --heads $upload_ref`;
    die $! if $!;
    die $? unless ($?==0 && chomp $upload_hash) 
	or ($?==256 && !length $upload_hash);
    my $hash;
    if (defined $dsc_hash) {
	die "missing git history even though dsc has hash"
	    unless length $upload_hash;
	$hash = $dsc_hash;
	ensure_we_have_orig();
    } else {
	$hash = generate_commit_from_dsc();
    }
    if (length $upload_hash) {
	die "not fast forward on last upload branch!".
	    " (archive's version left in DGIT_ARCHIVE)"
	    unless is_fast_fwd($dsc_hash, $upload_hash);
    }
    if ($upload_hash ne $hash) {
	cmdoutput qw(git update-ref -m), 'dgit fetch', $upload_ref, $hash;
    }
}

sub clone () {
    get_archive_dsc();
    $dsc_hash = $dsc->{$ourdscfield};
    if (defined $dsc_hash) {
	$dsc_hash =~ m/\w+/ or die "$dsc_hash $?";
	$dsc_hash = $&;
	print "last upload to archive specified git hash\n";
    } else {
	print "last upload to archive has NO git hash\n";
    }
    my $dstdir = "$package";
    if (check_for_git()) {
	print "cloning existing git history\n";
	runcmd qw(git clone --origin),$remotename, qw(-b), $suite, '--',
	    $alioth_git, $dstdir;
	chdir "$dstdir" or die "$dstdir $!";
	fetch_from_archive();
	runcmd qw(git reset --hard), rref(uploadbranch());
    } else {
	print "starting new git history\n";
	mkdir $dstdir or die "$dstdir $!";
	chdir "$dstdir" or die "$dstdir $!";
	runcmd qw(git init -q);
	open H, "> .git/HEAD" or die $!;
	print H "ref: ".lref(uploadbranch())."\n" or die $!;
	close H or die $!;
	runcmd qw(git remote add), $remotename, $alioth_git;
	runcmd "git config branch.$suite.remote $remotename";
	runcmd "git config branch.$suite.merge ".lref(uploadbranch());
	my $newhash = generate_commit_from_dsc();
	runcmd qw(git reset --hard), $newhash;
    }
    print "ready for work in $dstdir\n";
}

sub fetch () {
    if (check_for_git()) {
	runcmd qw(git fetch -p),$remotename,
	    '+refs/heads/*:refs/remotes/origin/*';
    }
    fetch_from_archive();
}

sub pull () {
    fetch();
    runcmd qw(git merge -m),"Merge from $suite [dgit]",lref(uploadbranch());
}

sub dopush () {
    runcmd qw(git diff --quiet HEAD);
    my $clogp = parsechangelog();
    $package = $clogp->{Source};
    my $dscfn = "${package}_$clogp->{Version}.dsc";
    stat $dscfn or die "$dscfn $!";
    $dsc = parsecontrol("../$dscfn");
    prep_ud();
    chdir $ud or die $!;
    print "checking that $dscfn corresponds to HEAD\n";
    runcmd qw(dpkg-source -x --), "../../../../$dscfn";
    my $tree = mktree_in_ud_from_only_subdir();
    chdir '../../../..' or die $!;
    runcmd qw(git diff --exit-code), $tree;
#fetch from alioth
#do fast forward check and maybe fake merge
#    if (!is_fast_fwd(mainbranch
#    runcmd qw(git fetch -p ), $alioth_git,
#        map { lref($_).":".rref($_) }
#        (uploadbranch());
    $dsc->{$ourdscfield} = rev_parse('HEAD');
    $dsc->save("../$dscfn.tmp") or die $!;
    rename "../$dscfn.tmp","../$dscfn" or die "$dscfn $!";
    if ($sign) {
	runcmd qw(git tag -s),@git_tag_opts,qw(-m),
	    "Release $dsc->{Version} for $suite [dgit]";
	unlink "../$dscfn.asc" or $!==&ENOENT or die "$dscfn.asc $!";
	runcmd qw(gpg --clearsign),@gpg_opts,"../$dscfn";
	rename "../$dscfn.asc","../$dscfn" or die "$dscfn $!";
    }
    if (!$nopush) {
	runcmd qw(git push),$remotename,"HEAD:".lref(uploadbranch());
	runcmd qw(dput),"../$dscfn";
    }
}

sub cmd_clone {
    if (@ARGV==1) {
	($package) = @ARGV;
    } elsif (@ARGV==2) {
	($package,$suite) = @ARGV;
    } else {
	die;
    }
    clone();
}

sub branchsuite () {
    my $branch = `git-symbolic-ref HEAD`;
    if ($branch =~ m#^refs/heads/dgit/([^/.]+)$#) {
	return $1;
    } else {
	return undef;
    }
}

sub cmd_fetch {
    my $clogp = parsechangelog();
    $package = $clogp->{Source};
    if (@ARGV==0) {
	$suite = branchsuite();
	$suite ||= $clogp->{Distribution};
	print "fetching from suite $suite\n";
    } elsif (@ARGV==1) {
	($suite) = @ARGV;
    } else {
	die;
    }
    fetch();
}

sub cmd_push {
    my $clogp = parsechangelog();
    $package = $clogp->{Source};
    if (@ARGV==0) {
	$suite = $clogp->{Distribution};
    } else {
	die;
    }
    dopush();
}

sub parseopts () {
    die if @ARGV && $ARGV[0] =~ m/^\-/;
}

parseopts();
die unless @ARGV;
my $cmd = shift @ARGV;
parseopts();

{ no strict qw(refs); &{"cmd_$cmd"}(); }