1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
|
package Dancer2::Core::Request::Upload;
# ABSTRACT: Class representing file upload requests
$Dancer2::Core::Request::Upload::VERSION = '1.1.0';
use Moo;
use Carp;
use File::Spec;
use Module::Runtime 'require_module';
use Dancer2::Core::Types;
use Dancer2::FileUtils qw(open_file);
has filename => (
is => 'ro',
isa => Str,
);
has tempname => (
is => 'ro',
isa => Str,
);
has headers => (
is => 'ro',
isa => HashRef,
);
has size => (
is => 'ro',
isa => Num,
);
sub file_handle {
my ($self) = @_;
return $self->{_fh} if defined $self->{_fh};
my $fh = open_file( '<', $self->tempname );
$self->{_fh} = $fh;
}
sub copy_to {
my ( $self, $target ) = @_;
require_module('File::Copy');
File::Copy::copy( $self->tempname, $target );
}
sub link_to {
my ( $self, $target ) = @_;
CORE::link( $self->tempname, $target );
}
sub content {
my ( $self, $layer ) = @_;
return $self->{_content}
if defined $self->{_content};
$layer = ':raw' unless $layer;
my $content = undef;
my $handle = $self->file_handle;
binmode( $handle, $layer );
while ( $handle->read( my $buffer, 8192 ) ) {
$content .= $buffer;
}
$self->{_content} = $content;
}
sub basename {
my ($self) = @_;
require_module('File::Basename');
File::Basename::basename( $self->filename );
}
sub type {
my $self = shift;
return $self->headers->{'Content-Type'};
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Dancer2::Core::Request::Upload - Class representing file upload requests
=head1 VERSION
version 1.1.0
=head1 DESCRIPTION
This class implements a representation of file uploads for Dancer2.
These objects are accessible within route handlers via the request->uploads
keyword. See L<Dancer2::Core::Request> for details.
=head1 ATTRIBUTES
=head2 filename
Filename as sent by client. optional. May not be undef.
=head2 tempname
The name of the temporary file the data has been saved to. Optional. May not be undef.
=head2 headers
A hash ref of the headers associated with this upload. optional. is read-write and a HashRef.
=head2 size
The size of the upload, in bytes. Optional.
=head1 METHODS
=head2 my $filename=$upload->filename;
Returns the filename (full path) as sent by the client.
=head2 my $tempname=$upload->tempname;
Returns the name of the temporary file the data has been saved to.
For example, in directory /tmp, and given a random name, with no file extension.
=head2 my $href=$upload->headers;
Returns a hashRef of the headers associated with this upload.
=head2 my $fh=$upload->file_handle;
Returns a read-only file handle on the temporary file.
=head2 $upload->copy_to('/path/to/target')
Copies the temporary file using File::Copy. Returns true for success,
false for failure.
=head2 $upload->link_to('/path/to/target');
Creates a hard link to the temporary file. Returns true for success,
false for failure.
=head2 my $content=$upload->content;
Returns a scalar containing the contents of the temporary file.
=head2 my $basename=$upload->basename;
Returns basename for "filename".
=head2 $upload->type
Returns the Content-Type of this upload.
=head1 SEE ALSO
L<Dancer2>
=head1 AUTHOR
Dancer Core Developers
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2023 by Alexis Sukrieh.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|
