uast/build.gradle


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95

buildscript {
  ext.kotlin_version = '1.0.5'
  ext.intellij_core_version = '171.3019.7'
  repositories {
    jcenter()
  }
  dependencies {
    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    classpath 'com.github.jengelman.gradle.plugins:shadow:1.2.3'
    classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7'
    classpath 'de.undercouch:gradle-download-task:3.1.2'
  }
}

String getUastVersion() {
  return System.getenv("ARTIFACT_VERSION") ?: "1.0"
}

apply from: 'updateDependencies.gradle'

allprojects {
  group = 'org.jetbrains.uast'
  version = getUastVersion()

  apply plugin: 'java'
  apply plugin: 'kotlin'
  apply plugin: 'com.github.johnrengelman.shadow'
  apply plugin: 'com.jfrog.bintray'
  apply plugin: "maven-publish"

  configurations {
    provided
  }

  sourceSets {
    main {
      compileClasspath += configurations.provided

      java.srcDirs = ['src']
      kotlin.srcDirs = ['src']
    }

    test {
      java.srcDirs = ['test']
      kotlin.srcDirs = ['test']
    }
  }

  compileJava {
    sourceCompatibility = 1.6
    targetCompatibility = 1.6
  }

  repositories {
    jcenter()
  }

  task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
  }

  bintray {
    user = System.getenv("BINTRAY_USER") ?: ""
    key = System.getenv("BINTRAY_API_KEY") ?: ""

    publications = ['UastPublication']

    pkg {
      repo = 'uast'
      name = 'uast'
      userOrg = 'kotlin'
      licenses = ['Apache-2.0']
      vcsUrl = SCM_URL

      version {
        name = getUastVersion()
        released = new Date()
      }
    }
  }

  publishing {
    publications {
      UastPublication(MavenPublication) {
        from components.java
        groupId 'org.jetbrains.uast'
        artifactId project.name
        version getUastVersion()

        artifact sourcesJar
      }
    }
  }
}