blob: 1e883e52a3326bd11da901129c7ed588eb94edb8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
#
# Copyright (C) 2000-2022 Kern Sibbald
# License: BSD 2-Clause; see file LICENSE-FOSS
#
######################################################################
#
# !!!!!!! IMPORTANT !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
#
# Edit only tray-monitor.pro.in -- tray-monitor.pro is built by the ./configure program
#
# !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
#
# CONFIG options for Windows are pulled from win32/qmake.conf
CONFIG += qt
#CONFIG += qt debug
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
cross-win32 {
LIBS += -mwindows -L../../win32/release32 -lbacula
INCLUDEPATH += ../../win32/compat
}
!cross-win32 {
LIBS += -L../../lib -lbaccfg -lbac -L../../findlib -lbacfind @OPENSSL_LIBS@
}
bins.path = /$(DESTDIR)@sbindir@
bins.files = .libs/bacula-tray-monitor
confs.path = /$(DESTDIR)@sysconfdir@
confs.commands = ./install_conf_file
TEMPLATE = app
TARGET = bacula-tray-monitor
QMAKE_EXTRA_TARGETS += depend
DEPENDPATH += .
INCLUDEPATH += ../.. .
QMAKE_CC = $(CXX)
LIBTOOL_LINK = @QMAKE_LIBTOOL@ --silent --tag=CXX --mode=link
LIBTOOL_INSTALL = @QMAKE_LIBTOOL@ --silent --mode=install
QMAKE_LINK = $${LIBTOOL_LINK} $(CXX)
QMAKE_INSTALL_PROGRAM = $${LIBTOOL_INSTALL} install -m @SBINPERM@ -p
QMAKE_CLEAN += obj/* .libs/* bacula-tray-monitor release/bacula-tray-monitor
QMAKE_CXXFLAGS += -DTRAY_MONITOR
QMAKE_CFLAGS += -DTRAY_MONITOR
INSTALLS = bins confs
RESOURCES = ../main.qrc
MOC_DIR = moc
OBJECTS_DIR = obj
UI_DIR = ui
# Main directory
HEADERS += tray-monitor.h tray_conf.h ../../lib/authenticatebase.h tray-ui.h fdstatus.h task.h ../util/fmtwidgetitem.h dirstatus.h conf.h sdstatus.h runjob.h status.h restorewizard.h filesmodel.h clientselectwizardpage.h jobselectwizardpage.h fileselectwizardpage.h restoreoptionswizardpage.h pluginwizardpage.h
SOURCES += tray-monitor.cpp tray_conf.cpp ../../lib/authenticatebase.cc fdstatus.cpp task.cpp authenticate.cpp ../util/fmtwidgetitem.cpp dirstatus.cpp sdstatus.cpp conf.cpp runjob.cpp status.cpp restorewizard.cpp clientselectwizardpage.cpp jobselectwizardpage.cpp fileselectwizardpage.cpp restoreoptionswizardpage.cpp pluginwizardpage.cpp
FORMS += fd-monitor.ui dir-monitor.ui sd-monitor.ui main-conf.ui res-conf.ui run.ui restorewizard.ui clientselectwizardpage.ui jobselectwizardpage.ui fileselectwizardpage.ui restoreoptionswizardpage.ui pluginwizardpage.ui
# CDP Client
CDP_DIR = ../../tools/cdp-client
HEADERS += $$CDP_DIR/backupservice.h $$CDP_DIR/folderwatcher.h desktop-gui/cdp-main-ui.h $$CDP_DIR/cdp.h
SOURCES += $$CDP_DIR/backupservice.cpp $$CDP_DIR/folderwatcher.cpp
INCLUDEPATH += $$CDP_DIR
# Journal
JOURNAL_DIR = ../../plugins/fd
HEADERS += $$JOURNAL_DIR/journal.h $$JOURNAL_DIR/file-record.h $$JOURNAL_DIR/folder-record.h $$JOURNAL_DIR/settings-record.h
SOURCES += $$JOURNAL_DIR/journal.c
INCLUDEPATH += $$JOURNAL_DIR
TRANSLATIONS += ts/tm_fr.ts ts/tm_de.ts ts/tm_ja.ts
### See https://wiki.debian.org/Hardening#Notes_for_packages_using_QMake
QMAKE_CPPFLAGS *= $(shell dpkg-buildflags --get CPPFLAGS)
QMAKE_CFLAGS *= $(shell "dpkg-buildflags --get CFLAGS; dpkg-buildflags --get CPPFLAGS")
QMAKE_CXXFLAGS *= $(shell "dpkg-buildflags --get CXXFLAGS; dpkg-buildflags --get CPPFLAGS")
QMAKE_LFLAGS *= $(shell dpkg-buildflags --get LDFLAGS)
|